10 '  SAVE "B:TOUJI",A
20 '  SAVE "B:TOUJI.CPY",A
30 '***************************************************************
40 '****  冬至の日における地軸の傾きと昼の長さ，夜の長さ　　　 ****
50 '****  1989年11月           山田 洋                         ****
60 '***************************************************************
70 SCREEN 3:CONSOLE 0,25,0,1:WIDTH 80,20:CLS 3
80 'DEFDBL A-H,O-Z
90 DIME=(((400+7)/8)*400*3+4)/4+1
100 DIM G%(DIME)
110 DIM XDD(200),YDD(200),CH(256)
120 GOSUB *FKEYNUL
130 ON STOP GOSUB *MENU:STOP ON
140 ON KEY GOSUB *F1,*F2,*F3,*F4,,,,,,*F10
150 KEY(1) ON:KEY(2) ON:KEY(3) ON:KEY(4) ON:KEY(10) ON
160 GOSUB *SETFKEY
170 IFLAG1=1:IFLAG2=1:IFLAG3=1  '入力はＯＮ
180 IFLAG4=-1                   '注意書はＯＦＦ
190 HTILE$=CHR$(&H55)+CHR$(&HFF)+CHR$(&HFF)   '薄黄色
200 'YTILE$=CHR$(&H55)+CHR$(&H55)+CHR$(&H55)  '灰色
210 YTILE$=CHR$(&HAA)+CHR$(&H0)+CHR$(&H0)     '暗青色
220 GOSUB *CH
230 TH$="":PH$="":PK$="" '地軸の傾き，緯度，経度のクリア−
240 PAY=3.141592653589794#
250 TR=120                '地球半径
260 TL=1.2*TR             '地軸の長さ　　　　　　　　　　　
270 IFLAG=1               '初めて描くかどうかの判断のため
280 LOCATE 5,0:COLOR 6
290 PRINT"***** 冬至における地軸の傾きと昼の長さ夜の長さの関係 *****":COLOR 7
300 X0=430:Y0=204    '画面の中心位置
310 WX1=-X0:WY1=-Y0:WX2=639-X0:WY2=399-Y0  'ワ−ルド座標
320 'WINDOW(WX1,WY1/.899)-(WX2,WY2/.899)   'FM-BASIC98用
330  WINDOW(WX1,WY1)-(WX2,WY2)             'N88BASIC用
340 GOSUB *NYUURYOKU
350 IF IFLAG=1 THEN GOSUB *MESSEAGE
360 LINE(-TL-16,-TL-16)-(TL+16,TL+16),0,BF   '地球を消す
370 GOSUB *TIKYUU
380 GOSUB *KEISAN
390 IF IFLAG=1 THEN GOSUB *KEISANHYOUJI ELSE GOSUB *SUUHYOUJI
400 'IFLAG=1    ' ゲット、プットを使わずに再び描く（遅いけど見た目に良い）
410  IFLAG=2    ' ゲット、プットを使う            （早いけどちらつく    )
420 GOTO 300
430 END
440 '
450 '
460 '******** メニューヘ戻る ************
470 *MENU
480 STOP OFF
490 KEY(1) OFF:KEY(2) OFF:KEY(3) OFF:KEY(4) OFF:KEY(10) OFF
500 GOSUB *FKEY0
510 RUN"MENU"
520 RETURN
530 '
540 '
550 '********* 注意書き表示＆消し ************
560 *CHUUI
570 XCHUUI=16*0:YCHUUI=20*6.5
580 XCL=16*14:YCL=20*8
590 LINE (MAP(XCHUUI,2),MAP(YCHUUI,3))-STEP(XCL,YCL),7,B
600 PAINT (MAP(XCHUUI+2,2),MAP(YCHUUI+2,3)),YTILE$,7
610 COLOR 7
620 LOCATE 2,7 :PRINT "--------  注意　--------"
630 LOCATE 2,8 :PRINT "地球儀などを使って実際に"
640 LOCATE 2,9 :PRINT "測ってみましょう。"
650 LOCATE 2,11:PRINT "いつも夜ばかりとか昼ばか"
660 LOCATE 2,12:PRINT "りという所もありますよ。
670 LOCATE 2,13:PRINT "地図帳で調べてみましょう。"
680 COLOR 7
690 RETURN
700 *CHUUIKESI
710 XCHUUI=16*0:YCHUUI=20*6.5
720 XCL=16*14:YCL=20*8
730 LINE (MAP(XCHUUI,2),MAP(YCHUUI,3))-STEP(XCL,YCL),0,BF
740 LOCATE 2,7 :PRINT "                        "
750 LOCATE 0,8 :PRINT "                            "
760 LOCATE 0,9 :PRINT "                            "
770 LOCATE 0,11:PRINT "                            "
780 LOCATE 0,12:PRINT "                            "
790 LOCATE 0,13:PRINT "                            "
800 RETURN
810 '
820 '
830 '******** メッセージ文  *******************
840 *MESSEAGE
850 COLOR 7
860 FOR I=1 TO 5 :LOCATE 74,4+2*I:PRINT "←":NEXT I    ' 太陽光の矢印
870 JI=6
880 LOCATE 77,JI+2:PRINT"太"
890 LOCATE 77,JI+4:PRINT"陽"
900 LOCATE 77,JI+6:PRINT"光"
910 RETURN
920 '
930 '
940 '******** 地球を描く **************
950 *TIKYUU
960 IF IFLAG=1 THEN GOSUB *TIKYUUSHOKI ELSE PUT@(MAP(-TR,0),MAP(-TR,1)),G%
970 IF IFLAG=1 THEN GET@(MAP(-TR,0),MAP(-TR,1))-STEP(2*TR,2*TR),G%
980 GOSUB *TIJIKU
990 GOSUB *SEKIDOU
1000 GOSUB *JITENITI
1010 RETURN
1020 '
1030 '
1040 '******** 入力  *******************
1050 *NYUURYOKU
1060 IF IFLAG<>1 THEN 1160
1070 NYUUX0=0:NYUUY0=2   '入力領域の左隅（ワード単位）
1080 NYUUXL=10:NYUUYL=3   '入力領域の枠の長さ（ワード単位）
1090 CLNYUU=7            '入力領域の枠の色
1100 LINE(MAP(16*NYUUX0,2),MAP(20*NYUUY0,3))-STEP(16*NYUUXL,20*NYUUYL),CLNYUU,B
1110 LINE(MAP(16*NYUUX0,2),MAP(20*NYUUY0+  20*NYUUYL/3,3))-STEP(16*NYUUXL,0),CLNYUU,
1120 LINE(MAP(16*NYUUX0,2),MAP(20*NYUUY0+2*20*NYUUYL/3,3))-STEP(16*NYUUXL,0),CLNYUU,
1130 LOCATE NYUUX0,NYUUY0:  PRINT " 地軸の傾き = "
1140 LOCATE NYUUX0,NYUUY0+1:PRINT " 緯度　　　 = "
1150 LOCATE NYUUX0,NYUUY0+2:PRINT " 経度　　　 = "
1160 XINP0=2*(NYUUX0+7):YINP0=NYUUY0
1170 IF IFLAG1=-1 AND IFLAG2=-1 AND IFLAG3=-1 THEN GOSUB *F1   '入力が選ばれなかった時の処理
1180 '-------  地軸の傾き入力 -------
1190 *INPTIJIKU
1200 X=XINP0:Y=YINP0
1210 INPFLG=1
1220 IF IFLAG1=-1 THEN *INPIDO
1230 GOSUB *INPUTT:IF N$<>"" THEN TH=VAL(N$) ELSE *THRETURN
1240 LOCATE X,Y:PRINT "                                   "
1250 TH$=N$
1260 *THRETURN
1270 TH=VAL(TH$):IF TH$="" THEN TH$="0"
1280 LOCATE X,Y:PRINT TH$
1290 IF TH=90 THEN TH=89.9999
1300 IF TH=-90 THEN TH=-89.9999
1310 THR=TH*PAY/180
1320 '--------  緯度の入力 -------
1330 *INPIDO
1340 INPFLG=2
1350 X=XINP0:Y=YINP0+1
1360 IF IFLAG2=-1 THEN *INPKEIDO
1370 GOSUB *INPUTT:IF N$<>"" THEN PH=VAL(N$) ELSE *PHRETURN
1380 LOCATE X,Y:PRINT "                                   "
1390 IF ABS(PH)>90 THEN GOTO 1370
1400 PH$=N$
1410 *PHRETURN
1420 PH=VAL(PH$):IF PH$="" THEN PH$="0"
1430 LOCATE X,Y:PRINT PH$
1440 IF PH=90 THEN PH=89.9999
1450 IF PH=-90 THEN PH=-89.9999
1460 PHR=PH*PAY/180
1470 '--------  経度の入力 -------
1480 *INPKEIDO
1490 INPFLG=3
1500 X=XINP0:Y=YINP0+2
1510 IF IFLAG3=-1 THEN 1600
1520 GOSUB *INPUTT:IF N$<>"" THEN PK=VAL(N$) ELSE *PKRETURN
1530 LOCATE X,Y:PRINT "                                   "
1540 IF ABS(PK)>180 THEN GOTO 1520
1550 PK$=N$
1560 *PKRETURN
1570 PK=VAL(PK$):IF PK$="" THEN PK$="0"
1580 LOCATE X,Y:PRINT PK$
1590 PKR=PK*PAY/180
1600 RETURN  350
1610 '
1620 '
1630 '***********  地球初期画図 *************
1640 *TIKYUUSHOKI
1650 CIRCLE(0,0),TR,7   '地球の外枠
1660 'CIRCLE(2,0),TR,7,.5*PAY,1.5*PAY,100000!     '日向と日影の堺目
1670 LINE(0,-TR)-(0,TR),7                         '日向と日影の堺目
1680  PAINT(2,0),HTILE$,7     '昼のペイント
1690  PAINT(-2,0),YTILE$,7    '夜のペイント
1700 'PAINT(2,0),6,7          '昼のペイント
1710 'PAINT(-2,0),1,7         '夜のペイント
1720 RETURN
1730 '
1740 '
1750 '*******    地軸を描く   ********
1760 *TIJIKU
1770 TLX1=TL*SIN(THR):TLY1=TL*COS(THR)
1780 TLX2=TR*SIN(THR):TLY2=TR*COS(THR)
1790 LINE(-TLX1,-TLY1)-(-TLX2,-TLY2),7
1800 LINE(TLX1,TLY1)-(TLX2,TLY2),7
1810 'KANJIN=&H4E    '半角N
1820 'KANJIN=&H14E   '1/4角N
1830  KANJIN=&H234E  '全角Ｎ
1840 PUT@ (MAP(-TLX1,0),MAP(-TLY1-16,1)),KANJI(KANJIN),XOR,2,0  'Ｎ極表示
1850 'KANJIS=&H53    '半角S
1860 'KANJIS=&H153   '1/4角S
1870  KANJIS=&H2353  '全角Ｓ
1880 PUT@ (MAP(TLX1,0),MAP(TLY1-16,1)),KANJI(KANJIS),XOR,7,0    'Ｓ極表示
1890 '********************************
1900 RETURN
1910 '
1920 '
1930 '************ 赤道を描く ****************
1940 *SEKIDOU
1950 R=TR                  '楕円の長径
1960 GYOUKA=0              '仰角
1970 XX0=0:YY0=0           '傾いていない時の楕円の中心
1980 CLD=2                 '楕円の色
1990 'GOSUB *DAEN
2000 XL=TR*COS(THR):YL=TR*SIN(THR):LINE(-XL,YL)-(XL,-YL),CLD
2010 RETURN
2020 '
2030 '
2040 '********** 自転位置を描く **************
2050 *JITENITI
2060 R=TR*COS(PHR)         '楕円の長径
2070 L=5*TR                'みる位置から楕円の中心までの距離
2080 'GYOUKA=ATN(R/L*SIN(PHR)*ABS(COS(THR))/(1-R/L*COS(PHR)))    '仰角
2090  GYOUKA=ATN(R/L*SIN(PHR)              /(1-R/L*COS(PHR)))    '仰角
2100 'GYOUKA=0
2110 XX0=0:YY0=TR*SIN(PHR) '傾いていない時の楕円の中心
2120 CLD=4                 '楕円の色
2130 GOSUB *DAEN
2140 RETURN
2150 *DAEN
2160 NS=20 ' 描くドット数
2170 TRDD=R*SIN(GYOUKA)
2180 FOR IS=0 TO NS
2190 HR=PAY*IS/NS
2200 X=R*COS(HR)+XX0:Y=TRDD*SIN(HR)+YY0
2210 '--------（地軸の傾きによる回転変換）--------
2220 XX=X*COS(THR)-Y*SIN(THR)
2230 YY=X*SIN(THR)+Y*COS(THR)
2240 XDD(IS)=XX:YDD(IS)=YY
2250 NEXT IS
2260 FOR IS=1 TO NS
2270 LINE(XDD(IS-1),-YDD(IS-1))-(XDD(IS),-YDD(IS)),CLD
2280 LINE(XDD(IS-1),-YDD(IS-1)+1)-(XDD(IS),-YDD(IS)+1),CLD
2290 NEXT IS
2300 RETURN
2310 '
2320 '
2330 '********* 計算 **************
2340 *KEISAN
2350 '**** 昼だけ，夜だけの判断 ****
2360 COSP=TAN(THR)*TAN(PHR)
2370 IF THR>=.5*PAY AND THR<1.5*PAY THEN COSP=-COSP
2380 IF COSP=0 THEN P=PAY:GOTO 2430
2390 IF COSP>=1 THEN P=0:GOTO 2430
2400 IF COSP<=-1 THEN P=2*PAY:GOTO 2430
2410 P=2*ATN(SQR(1/(COSP*COSP)-1))
2420 IF COSP<0 THEN P=2*PAY-P
2430 HIRUHI=.5*P/PAY
2440 YORUHI=1-HIRUHI
2442 YORUHI=1-HIRUHI
2444 HIRU=24*HIRUHI
2450 RETURN
2460 *KEISANHYOUJI
2470 NXW=0:NYW=15              '計算表示枠の左隅（ワード単位）
2480 NXL=16:NYL=2              '計算表示枠の長さ（ワード単位）
2490 XHYOU=NXW*16:YHYOU=NYW*20 '計算表示枠の左隅
2500 XWAKU=NXL*16:YWAKU=NYL*20 '計算表示枠の長さ
2510 CLWAKU=5                  '計算表示枠の色
2520 '------ 計算表示枠を描く -------
2530 GL=5   '棒グラフの長さ（ワード単位）
2540 GH=.2   '棒グラフの巾（ワード単位）
2550 'LINE (MAP(XHYOU,2),MAP(YHYOU+20,3))-STEP(XWAKU,YWAKU),CLWAKU,B
2560 'LINE (MAP(XHYOU,2),MAP(YHYOU+20+.5*YWAKU,3))-STEP(XWAKU,0),CLWAKU,B
2570 'LINE (MAP(XHYOU,2),MAP(YHYOU,3))-STEP(XWAKU-16*GL,YWAKU+20),CLWAKU,B
2580 'LOCATE 2*NXW,NYW  :PRINT" １日の長さに対する比 "
2590 'LOCATE 2*NXW,NYW+1:PRINT" 昼の長さ（比）="
2591 LINE (MAP(XHYOU,2),MAP(YHYOU+20,3))-STEP(XWAKU,YWAKU),CLWAKU,B
2592 LINE (MAP(XHYOU,2),MAP(YHYOU+20+.5*YWAKU,3))-STEP(XWAKU,0),CLWAKU,B
2593 LINE (MAP(XHYOU+XWAKU-16*GL,2),MAP(YHYOU+YWAKU-20,3))-STEP(0,40),CLWAKU,B
2594 LOCATE 2*NXW,NYW+1:PRINT" 昼      時間"
2595 LOCATE 2*NXW,NYW+2:PRINT" 夜      時間"
2596 LINE (MAP(XHYOU+XWAKU-8*GL+1,2),MAP(YHYOU+20,3))-STEP(0,-3),CLWAKU,BF
2620 '---- グラフの目盛り ----
2630 'PUT@ (XHYOU+XWAKU-8*GL-6,YHYOU+ 5),KANJI(&H130),XOR,7,0  '1/4角 0
2640 'PUT@ (XHYOU+XWAKU-8*GL  ,YHYOU+ 5),KANJI(&H12E),XOR,7,0  '1/4角 .
2650 'PUT@ (XHYOU+XWAKU-8*GL+6,YHYOU+ 5),KANJI(&H135),XOR,7,0  '1/4角 5
2660 'LINE (MAP(XHYOU+XWAKU,2),MAP(YHYOU+20,3))-STEP(0,-3),CLWAKU,BF
2670 'PUT@ (XHYOU+XWAKU-4     ,YHYOU+ 5),KANJI(&H131),XOR,7,0  '1/4角 1
2671 LINE (MAP(XHYOU+XWAKU-8*GL+1,2),MAP(YHYOU+20,3))-STEP(0,-3),CLWAKU,B
2672 PUT@ (XHYOU+XWAKU-8*GL-8,YHYOU+ 5),KANJI(&H131),PSET,7,0  '1/4角 1
2673 PUT@ (XHYOU+XWAKU-8*GL  ,YHYOU+ 5),KANJI(&H132),PSET,7,0  '1/4角 2
2674 LINE (MAP(XHYOU+XWAKU,2),MAP(YHYOU+20,3))-STEP(0,-3),CLWAKU,B
2675 PUT@ (XHYOU+XWAKU-8,YHYOU+ 5),KANJI(&H132),PSET,7,0  '1/4角 2
2676 PUT@ (XHYOU+XWAKU    ,YHYOU+ 5),KANJI(&H134),PSET,7,0  '1/4角 4
2680 *SUUHYOUJI
2690 '----- 計算数値を書く ------
2700 'LOCATE 2*NXW+16,NYW+1:PRINT USING "##.##";HIRUHI
2710 'LOCATE 2*NXW+16,NYW+2:PRINT USING "##.##";YORUHI
2712 COLOR 6:LOCATE 2*NXW+ 4,NYW+1:PRINT USING "##.##";HIRU
2714         LOCATE 2*NXW+ 4,NYW+2:PRINT USING "##.##";YORU:COLOR 7
2720 '----- 棒グラフを描く -----
2730 '  昼の棒グラフ
2740 LINE (MAP(XHYOU+XWAKU-16*GL+1,2),MAP(YHYOU+30-.5*20*GH,3))-STEP(GL*16-2,20*GH),0,BF
2750 GGL=(16*GL-2)*HIRUHI
2760 IF GGL<1 THEN 2800
2770 LINE (MAP(XHYOU+XWAKU-16*GL+1,2),MAP(YHYOU+30-.5*20*GH,3))-STEP(GGL,20*GH),7,B
2780 PAINT STEP(-1,-1),HTILE$,7
2790 '  夜の棒グラフ
2800 LINE (MAP(XHYOU+XWAKU-16*GL+1,2),MAP(YHYOU+50-.5*20*GH,3))-STEP(GL*16-2,20*GH),0,BF
2810 GGL=(16*GL-2)*YORUHI
2820 IF GGL<1 THEN 2850
2830 LINE (MAP(XHYOU+XWAKU-16*GL+1,2),MAP(YHYOU+50-.5*20*GH,3))-STEP(GGL,20*GH),1,B
2840 PAINT STEP(-1,-1),YTILE$,1
2850 RETURN
2860 '
2870 '
2880 '********** 数値のインプット ***********
2890 *INPUTT
2900 N$="":DX=0
2910 AA$=INKEY$:IF AA$<>"" THEN 2910
2920 V$=""
2930 LOCATE X+DX,Y:V$=INPUT$(1)
2940 IF V$="" THEN 2930
2950 CHV=CH(ASC(V$))
2960 ON CHV GOSUB *SUU,*KETTEI,*SAKUJYO
2970 GOTO 2920
2980 *INPUTTRETURN
2990 RETURN
3000 *CH
3010 FOR I=48 TO 57:CH(I)=1:NEXT I '1,2,3,････,9 ｷｰ
3020 CH(43)=1                      '+ ｷｰ
3030 CH(45)=1                      '- ｷｰ
3040 CH(46)=1                      '. ｷｰ
3050 CH(13)=2                      'RETURN ｷｰ
3060 CH(127)=3                     'DEL ｷｰ
3070 CH(8)=3                       'BS  ｷｰ
3080 CH(27)=4                      'ESC ｷｰ
3090 RETURN
3100 *SUU
3110 N$=N$+V$
3120 LOCATE X+DX,Y:PRINT V$;:DX=DX+1
3130 RETURN
3140 *KETTEI
3150 RETURN 2990
3160 *SAKUJYO
3170 IF N$="" THEN RETURN
3180 DX=DX-1
3190 N$=LEFT$(N$,DX)
3200 LOCATE X,Y:PRINT "               ";
3210 LOCATE X,Y:PRINT N$;
3220 RETURN
3230 '
3240 '
3250 '******************** ファンクションキーの設定 ***************************
3260 *SETFKEY
3270 FFAST=9                  'ファンクションキ−枠の始め
3280 FWAKUX=16*2+3            'ファンクションキ−枠の横の長さ
3290 FWAKUY=20                'ファンクションキ−枠の縦の長さ
3300 FKAN=22                  'ファンクションキ−枠間の長さ
3310 FOR I=1 TO 4
3320 LINE(MAP(FFAST+(FKAN+FWAKUX)*(I-1),2),MAP(399-FWAKUY,3))-STEP(FWAKUX,FWAKUY),7,B
3330 NEXT I
3340 I=10
3350 LINE(MAP(FFAST+(FKAN+FWAKUX)*(I-1),2),MAP(399-FWAKUY,3))-STEP(FWAKUX,FWAKUY),7,B
3360 PUT@ (FFAST                   +2,401-FWAKUY),KANJI(&H434F),PSET,7,1 '地
3370 PUT@ (FFAST                +16+2,401-FWAKUY),KANJI(&H3C34),PSET,7,1 '軸
3380 PUT@ (FFAST+(FKAN+FWAKUX)     +2,401-FWAKUY),KANJI(&H305E),PSET,7,1 '緯
3390 PUT@ (FFAST+(FKAN+FWAKUX)  +16+2,401-FWAKUY),KANJI(&H4559),PSET,7,1 '度
3400 PUT@ (FFAST+(FKAN+FWAKUX)*2+   2,401-FWAKUY),KANJI(&H3750),PSET,7,1 '経
3410 PUT@ (FFAST+(FKAN+FWAKUX)*2+16+2,401-FWAKUY),KANJI(&H4559),PSET,7,1 '度
3420 PUT@ (FFAST+(FKAN+FWAKUX)*3+   2,401-FWAKUY),KANJI(&H436D),PSET,7,0 '注
3430 PUT@ (FFAST+(FKAN+FWAKUX)*3+16+2,401-FWAKUY),KANJI(&H3055),PSET,7,0 '意
3440 PUT@ (FFAST+(FKAN+FWAKUX)*9+   2,401-FWAKUY),KANJI(&H3D2A),PSET,7,0 '終
3450 PUT@ (FFAST+(FKAN+FWAKUX)*9+16+2,401-FWAKUY),KANJI(&H246A),PSET,7,0 'り
3460 RETURN
3470 '
3480 '
3490 '******** ファンクションキーによる割り込みサブルーチン *********
3500 *F1
3510 IFLAG1=-IFLAG1
3520 CLF=(1+IFLAG1)/2
3530 PUT@ (FFAST                   +2,401-FWAKUY),KANJI(&H434F),PSET,7,CLF '地
3540 PUT@ (FFAST                +16+2,401-FWAKUY),KANJI(&H3C34),PSET,7,CLF '軸
3550 IF IFLAG1=-1 AND INPFLG=1 THEN RETURN *INPUTTRETURN
3560 RETURN
3570 *F2
3580 IFLAG2=-IFLAG2
3590 CLF=(1+IFLAG2)/2
3600 PUT@ (FFAST+(FKAN+FWAKUX)     +2,401-FWAKUY),KANJI(&H305E),PSET,7,CLF '緯
3610 PUT@ (FFAST+(FKAN+FWAKUX)  +16+2,401-FWAKUY),KANJI(&H4559),PSET,7,CLF '度
3620 IF IFLAG2=-1 AND INPFLG=2 THEN RETURN *INPUTTRETURN
3630 RETURN
3640 *F3
3650 IFLAG3=-IFLAG3
3660 CLF=(1+IFLAG3)/2
3670 PUT@ (FFAST+(FKAN+FWAKUX)*2+   2,401-FWAKUY),KANJI(&H3750),PSET,7,CLF '経
3680 PUT@ (FFAST+(FKAN+FWAKUX)*2+16+2,401-FWAKUY),KANJI(&H4559),PSET,7,CLF '度
3690 IF IFLAG3=-1 AND INPFLG=3 THEN RETURN *INPUTTRETURN
3700 RETURN
3710 *F4
3720 IFLAG4=-IFLAG4
3730 CLF=(1+IFLAG4)*2/2
3740 PUT@ (FFAST+(FKAN+FWAKUX)*3+   2,401-FWAKUY),KANJI(&H436D),PSET,7,CLF '注
3750 PUT@ (FFAST+(FKAN+FWAKUX)*3+16+2,401-FWAKUY),KANJI(&H3055),PSET,7,CLF '意
3760 IF IFLAG4=1 THEN GOSUB *CHUUI ELSE *CHUUIKESI
3770 RETURN
3780 *F10
3790 PUT@ (FFAST+(FKAN+FWAKUX)*9+   2,401-FWAKUY),KANJI(&H3D2A),PSET,7,2   '終
3800 PUT@ (FFAST+(FKAN+FWAKUX)*9+16+2,401-FWAKUY),KANJI(&H246A),PSET,7,2   'り
3810 GOSUB *MENU
3820 RETURN
3830 '
3840 '
3850 '********* ファンクションキーのセット**********
3860 *FKEY0
3870 KEY 1,"load "+CHR$(&H22):KEY 2,"auto":KEY 3,"go to":KEY 4,"list ":KEY 5,"run"+CHR$(13):KEY 6,"save "+CHR$(&H22):KEY 7,"key":KEY 8,"print ":KEY 9,"edit ."+CHR$(13):KEY 10,"cont"+CHR$(13)
3880 RETURN
3890 *FKEYNUL
3900 KEY 1,"":KEY 2,"":KEY 3,"":KEY 4,"":KEY 5,"":KEY 6,"":KEY 7,"":KEY 8,"":KEY 9,"":KEY 10,""
3910 RETURN